IR:

vL: 0 | vR: 0

// RoboSim v1.0 — Runtime Arduino JS

// Motores: IN1=5 IN2=6 (izq) | IN3=9 IN4=10 (der)

// Sensores: A0..A4 → 0=línea / 1023=blanco

// Listo. Presioná Ejecutar

sketch.ino Arduino C++ → JS transpiler

// Velocista seguidor de linea - 5 sensores IR
// analogRead: 0 = linea negra, 1023 = pista clara
// Sensores activos: A0, A1, A2, A3, A4
// Motores con reversa: pin A adelante, pin B atras
// Ejemplo base: sigue la linea sin busqueda de rescate.
// Si se sale, avanza recto: el simulador no lo "salva" solo.

#define MOTOR_IZQ_A 5
#define MOTOR_IZQ_B 6
#define MOTOR_DER_A 9
#define MOTOR_DER_B 10

#define SENSOR_COUNT 5
#define VEL_RECTA  190
#define VEL_CURVA  130
#define KP         14
#define KD         24

// En Arduino Uno A6/A7 no existen como constantes, pero el ADC del simulador
// acepta canales 6 y 7 para probar barras velocistas de hasta 8 sensores.
#ifndef A6
#define A6 20
#endif
#ifndef A7
#define A7 21
#endif

const byte sensorPins[SENSOR_COUNT] = { A0, A1, A2, A3, A4 };
const int sensorWeights[SENSOR_COUNT] = { -200, -100, 0, 100, 200 };

int sensores[SENSOR_COUNT];
int linea[SENSOR_COUNT];
int error, errorFiltrado, ultimoError, derivada, correccion;
int velIzq, velDer, base;

void motorIzq(int vel) {
  vel = constrain(vel, -255, 255);
  if (vel >= 0) {
    analogWrite(MOTOR_IZQ_A, vel);
    analogWrite(MOTOR_IZQ_B, 0);
  } else {
    analogWrite(MOTOR_IZQ_A, 0);
    analogWrite(MOTOR_IZQ_B, -vel);
  }
}

void motorDer(int vel) {
  vel = constrain(vel, -255, 255);
  if (vel >= 0) {
    analogWrite(MOTOR_DER_A, vel);
    analogWrite(MOTOR_DER_B, 0);
  } else {
    analogWrite(MOTOR_DER_A, 0);
    analogWrite(MOTOR_DER_B, -vel);
  }
}

void setup() {
  Serial.begin(9600);
  Serial.println("Velocista PID iniciado - 5 sensores");
}

void loop() {
  long suma = 0;
  long ponderado = 0;

for (byte i = 0; i < SENSOR_COUNT; i++) {
    sensores[i] = analogRead(sensorPins[i]);
    linea[i] = 1023 - sensores[i];
    if (linea[i] < 55) linea[i] = 0;
    suma += linea[i];
    ponderado += (long)linea[i] * sensorWeights[i];
  }

if (suma < 80) {
    // Sin rescate: si perdio la linea, sigue recto.
    // Esto deja ver cuando el PID no alcanza para sostener la curva.
    motorIzq(VEL_CURVA);
    motorDer(VEL_CURVA);
    delay(4);
    return;
  }

// Error ponderado: negativo = linea a la izquierda, positivo = derecha.
  error = ponderado / suma;
  errorFiltrado = (errorFiltrado * 3 + error) / 4;
  if (abs(errorFiltrado) < 8) errorFiltrado = 0;

derivada = errorFiltrado - ultimoError;
  ultimoError = errorFiltrado;

base = VEL_RECTA - min(abs(errorFiltrado), 170) * 2 / 7;
  if (base < VEL_CURVA) base = VEL_CURVA;

correccion = (KP * errorFiltrado + KD * derivada) / 10;

velIzq = constrain(base + correccion, -90, 255);
  velDer = constrain(base - correccion, -90, 255);

motorIzq(velIzq);
  motorDer(velDer);

delay(4);
}

Mapa de pines

Motor Izq +MOTOR_IZQ_A = 5

Motor Izq −MOTOR_IZQ_B = 6

Motor Der +MOTOR_DER_A = 9

Motor Der −MOTOR_DER_B = 10